pkg://kdeartwork-3.0.1.tar.bz2:10917073/kdeartwork-3.0.1/configure.in  downloads

dnl    This file is part of the KDE libraries/packages
dnl    Copyright (C) 2001 Stephan Kulow (coolo@kde.org)
 
dnl    This file is free software; you can redistribute it and/or
dnl    modify it under the terms of the GNU Library General Public
dnl    License as published by the Free Software Foundation; either
dnl    version 2 of the License, or (at your option) any later version.
 
dnl    This library is distributed in the hope that it will be useful,
dnl    but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
dnl    Library General Public License for more details.
 
dnl    You should have received a copy of the GNU Library General Public License
dnl    along with this library; see the file COPYING.LIB.  If not, write to
dnl    the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
dnl    Boston, MA 02111-1307, USA.

# Original Author was Kalle@kde.org
# I lifted it in some mater. (Stephan Kulow)
# I used much code from Janos Farkas

dnl Process this file with autoconf to produce a configure script.

AC_INIT(acinclude.m4) dnl a source file from your sub dir

dnl This is so we can use kde-common
AC_CONFIG_AUX_DIR(admin)

dnl This ksh/zsh feature conflicts with `cd blah ; pwd`
unset CDPATH

dnl Checking host/target/build systems, for make, install etc.
AC_CANONICAL_SYSTEM 
dnl Perform program name transformation
AC_ARG_PROGRAM

dnl Automake doc recommends to do this only here. (Janos)
AM_INIT_AUTOMAKE(kdeartwork, "3.0.1") dnl searches for some needed programs

KDE_SET_PREFIX

dnl generate the config header
AM_CONFIG_HEADER(config.h) dnl at the distribution this done

dnl Checks for programs.
AC_CHECK_COMPILERS
AC_ENABLE_SHARED(yes)
AC_ENABLE_STATIC(no)
KDE_PROG_LIBTOOL

dnl for NLS support. Call them in this order!
dnl WITH_NLS is for the po files
AM_KDE_WITH_NLS

dnl KDE_USE_QT
AC_PATH_KDE
#MIN_CONFIG

dnl Themes are installed by the toplevel Makefile.am
DO_NOT_COMPILE="$DO_NOT_COMPILE Themes"

AC_MSG_CHECKING(for Qt with OpenGL support)
AC_CACHE_VAL(ac_cv_kde_qt_has_opengl,
[
  AC_LANG_SAVE
  AC_LANG_CPLUSPLUS

  save_CXXFLAGS="$CXXFLAGS"
  save_LIBS="$LIBS"
  save_LDFLAGS="$LDFLAGS"

  CXXFLAGS="$CXXFLAGS -I$qt_incdir $all_includes"
  LDFLAGS="$LDFLAGS -L$qt_libdir $all_libraries $USER_LDFLAGS $KDE_MT_LDFLAGS"
  LIBS="$LIBS $LIBQT $KDE_MT_LIBS"

  AC_TRY_LINK([
  #include <qglwidget.h>
  ],
  [
   QGLWidget = new QGLWidget(0);
  ],
  ac_cv_kde_qt_has_opengl=yes,
  ac_cv_kde_qt_has_opengl=no)

  CXXFLAGS="$save_CXXFLAGS"
  LIBS="$save_LIBS"
  LDFLAGS="$save_LDFLAGS"
  AC_LANG_RESTORE
])
AC_MSG_RESULT($ac_cv_kde_qt_has_opengl)

AC_HAVE_GL([

if test "$ac_cv_kde_qt_has_opengl" = "yes"; then
  GL_XSAVERS="kmorph3d.kss kspace.kss kpipes.kss"
  GL_KSAVERS="kfountain.kss kwave.kss kgravity.kss"
  GL_DESKTOP_FILES="KGravity.desktop KWave.desktop KFountain.desktop"
else
  dnl remove those that need -enable-opengl in Qt
  GL_XSAVERS="kmorph3d.kss kspace.kss kpipes.kss"
  GL_KSAVERS=""
  GL_DESKTOP_FILES=""
fi

ac_save_CPPFLAGS="$CPPFLAGS"
CPPFLAGS="-I$GL_INCLUDE $CPPFLAGS $X_INCLUDES"
AC_CHECK_HEADERS(GL/xmesa.h GL/glut.h memory.h)
CPPFLAGS="$ac_save_CPPFLAGS"
],
GL_XSAVERS=""
GL_KSAVERS="")
AC_SUBST(GL_KSAVERS)
AC_SUBST(GL_XSAVERS)
AC_SUBST(GL_DESKTOP_FILES)


AC_CHECK_FUNCS(gettimeofday)

AC_HAVE_DPMS()
KDE_CREATE_SUBDIRSLIST
AC_OUTPUT( \
./Makefile \
icewm-themes/Makefile \
icewm-themes/MenschMaschine/Makefile \
icewm-themes/Model/Makefile \
kscreensaver/Makefile \
kscreensaver/kdesavers/Makefile \
kscreensaver/kpartsaver/Makefile \
kscreensaver/kxsconfig/Makefile \
kscreensaver/kxsconfig/config/Makefile \
kscreensaver/xsavers/Makefile \
kwin-styles/Makefile \
kwin-styles/cde/Makefile \
kwin-styles/cde/config/Makefile \
kwin-styles/glow/Makefile \
kwin-styles/glow/config/Makefile \
kwin-styles/openlook/Makefile \
kworldclock/Makefile \
kworldclock/alt/Makefile \
kworldclock/bio/Makefile \
kworldclock/caida/Makefile \
kworldclock/caida_bw/Makefile \
kworldclock/depths/Makefile \
kworldclock/mggd/Makefile \
kworldclock/rainfall/Makefile \
sounds/Makefile \
styles/Makefile \
styles/dotnet/Makefile \
wallpapers/Makefile \
)
dnl put here things which have to be done as very last part of configure

all_tests=fine

if test -z "$GL_XSAVERS"; then
  echo ""
  echo "OpenGL support could not be detected or was disabled."
  echo "Some of the screensavers have been removed from compilation."
  echo""
  all_tests=bad
fi

if test "$all_tests" = "fine"; then
  echo ""
  echo "Good - your configure finished. Start make now"
  echo ""
fi

if test "$all_tests" = "bad"; then
  echo ""
  echo "Please remove the file config.cache after changing your setup"
  echo "so that configure will detect the new situation next time."
  echo ""
fi